{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/release-20.03";
    nixpkgs-unstable.url = "github:nixos/nixpkgs-channels/nixos-unstable";
  };

  outputs = { self, nixpkgs, nixpkgs-unstable, nix }: {
    nixosConfigurations = let
      mkMachine = hostName:
        nixpkgs.lib.nixosSystem {
          system = "x86_64-linux";
          modules = [
            { networking.hostName = hostName; }
            { nixpkgs.overlays = [ (import ./overlay.nix nixpkgs-unstable) ]; }
            ./configuration.nix
          ];
        };

      installer = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          "${nixpkgs}/nixos/modules/installer/cd-dvd/installation-cd-minimal.nix"
          { nixpkgs.overlays = [ nix.overlay ]; }
          {
            nix = {
              binaryCaches = [
                "https://cache.nixos.org"
                "http://your-local-substituter:1234"
              ];
              binaryCachePublicKeys = [
                "hydra.nixos.org-1:CNHJZBh9K4tP3EKF6FkkgeVYsS3ohTl+oS0Qa8bezVs="
                "your-local-builder-1:<...>"
              ];
              registry.self.flake = self;
            };
          }
        ];
      };
    in {
      inherit installer;
    } // builtins.listToAttrs (map (name: {
      inherit name;
      value = mkMachine name;
    }) [ "machine1" "machine2" "machine3" ]);
  };
}